eleni.mutantstargoat.com Git - lighthouse/blob - sdr/sky.f.glsl

   1 varying vec3 local_pos;
   2
   3 uniform float alpha;
   4
   5 #define PI      3.141592653589793
   6 #define TWO_PI  (2.0 * PI)
   7
   8 float fbm(vec3 p, int octaves);
   9 float snoise(vec3 p);
  10 float clouds(vec3 p);
  11
  12 void main()
  13 {
  14         vec3 lpos = normalize(local_pos);
  15
  16         float cval = clouds(lpos * vec3(4.5, 4.5, 4.5));
  17         float alt = min(lpos.y * 2.0 + 0.5, 1.0);
  18
  19         //const vec3 col_hor = vec3(0.96, 0.55, 0.98);
  20         const vec3 col_hor = vec3(0.95, 0.38, 0.54);
  21         const vec3 col_zen = vec3(0.08, 0.18, 0.4);
  22
  23         vec3 skycol = mix(col_hor, col_zen, alt);
  24
  25         gl_FragColor.rgb = mix(skycol, vec3(0.0, 0.0, 0.0), cval);
  26         gl_FragColor.a = alpha;
  27 }
  28
  29 const float cloud_dens = 0.25;
  30 const float cloud_smooth = 1.0;
  31 const float cloud_alpha = 0.4;
  32
  33 float clouds(vec3 p)
  34 {
  35         float hor = clamp(p.y * 2.0, 0.0, 1.0);
  36         float nval = fbm(p * vec3(0.2, 1.0, 0.2), 5);
  37         float res = smoothstep(cloud_dens - cloud_smooth * 0.5,
  38                         cloud_dens + cloud_smooth * 0.5, nval);
  39         return res * hor * cloud_alpha;
  40 }
  41
  42 float fbm(vec3 p, int octaves)
  43 {
  44         float res = 0.0;
  45         float freq = 1.0;
  46         float s = 1.0;
  47
  48         for(int i=0; i<octaves; i++) {
  49                 res += snoise(p * freq) * s;
  50                 freq *= 2.0;
  51                 s *= 0.5;
  52         }
  53         return res;
  54 }
  55
  56 //
  57 // Description : Array and textureless GLSL 2D/3D/4D simplex
  58 //               noise functions.
  59 //      Author : Ian McEwan, Ashima Arts.
  60 //  Maintainer : ijm
  61 //     Lastmod : 20110822 (ijm)
  62 //     License : Copyright (C) 2011 Ashima Arts. All rights reserved.
  63 //               Distributed under the MIT License. See LICENSE file.
  64 //               https://github.com/ashima/webgl-noise
  65 //
  66
  67 vec3 mod289(vec3 x) {
  68   return x - floor(x * (1.0 / 289.0)) * 289.0;
  69 }
  70
  71 vec4 mod289(vec4 x) {
  72   return x - floor(x * (1.0 / 289.0)) * 289.0;
  73 }
  74
  75 vec4 permute(vec4 x) {
  76      return mod289(((x*34.0)+1.0)*x);
  77 }
  78
  79 vec4 taylorInvSqrt(vec4 r)
  80 {
  81   return 1.79284291400159 - 0.85373472095314 * r;
  82 }
  83
  84 float snoise(vec3 v)
  85   {
  86   const vec2  C = vec2(1.0/6.0, 1.0/3.0) ;
  87   const vec4  D = vec4(0.0, 0.5, 1.0, 2.0);
  88
  89 // First corner
  90   vec3 i  = floor(v + dot(v, C.yyy) );
  91   vec3 x0 =   v - i + dot(i, C.xxx) ;
  92
  93 // Other corners
  94   vec3 g = step(x0.yzx, x0.xyz);
  95   vec3 l = 1.0 - g;
  96   vec3 i1 = min( g.xyz, l.zxy );
  97   vec3 i2 = max( g.xyz, l.zxy );
  98
  99   //   x0 = x0 - 0.0 + 0.0 * C.xxx;
 100   //   x1 = x0 - i1  + 1.0 * C.xxx;
 101   //   x2 = x0 - i2  + 2.0 * C.xxx;
 102   //   x3 = x0 - 1.0 + 3.0 * C.xxx;
 103   vec3 x1 = x0 - i1 + C.xxx;
 104   vec3 x2 = x0 - i2 + C.yyy; // 2.0*C.x = 1/3 = C.y
 105   vec3 x3 = x0 - D.yyy;      // -1.0+3.0*C.x = -0.5 = -D.y
 106
 107 // Permutations
 108   i = mod289(i);
 109   vec4 p = permute( permute( permute(
 110              i.z + vec4(0.0, i1.z, i2.z, 1.0 ))
 111            + i.y + vec4(0.0, i1.y, i2.y, 1.0 ))
 112            + i.x + vec4(0.0, i1.x, i2.x, 1.0 ));
 113
 114 // Gradients: 7x7 points over a square, mapped onto an octahedron.
 115 // The ring size 17*17 = 289 is close to a multiple of 49 (49*6 = 294)
 116   float n_ = 0.142857142857; // 1.0/7.0
 117   vec3  ns = n_ * D.wyz - D.xzx;
 118
 119   vec4 j = p - 49.0 * floor(p * ns.z * ns.z);  //  mod(p,7*7)
 120
 121   vec4 x_ = floor(j * ns.z);
 122   vec4 y_ = floor(j - 7.0 * x_ );    // mod(j,N)
 123
 124   vec4 x = x_ *ns.x + ns.yyyy;
 125   vec4 y = y_ *ns.x + ns.yyyy;
 126   vec4 h = 1.0 - abs(x) - abs(y);
 127
 128   vec4 b0 = vec4( x.xy, y.xy );
 129   vec4 b1 = vec4( x.zw, y.zw );
 130
 131   //vec4 s0 = vec4(lessThan(b0,0.0))*2.0 - 1.0;
 132   //vec4 s1 = vec4(lessThan(b1,0.0))*2.0 - 1.0;
 133   vec4 s0 = floor(b0)*2.0 + 1.0;
 134   vec4 s1 = floor(b1)*2.0 + 1.0;
 135   vec4 sh = -step(h, vec4(0.0));
 136
 137   vec4 a0 = b0.xzyw + s0.xzyw*sh.xxyy ;
 138   vec4 a1 = b1.xzyw + s1.xzyw*sh.zzww ;
 139
 140   vec3 p0 = vec3(a0.xy,h.x);
 141   vec3 p1 = vec3(a0.zw,h.y);
 142   vec3 p2 = vec3(a1.xy,h.z);
 143   vec3 p3 = vec3(a1.zw,h.w);
 144
 145 //Normalise gradients
 146   vec4 norm = taylorInvSqrt(vec4(dot(p0,p0), dot(p1,p1), dot(p2, p2), dot(p3,p3)));
 147   p0 *= norm.x;
 148   p1 *= norm.y;
 149   p2 *= norm.z;
 150   p3 *= norm.w;
 151
 152 // Mix final noise value
 153   vec4 m = max(0.6 - vec4(dot(x0,x0), dot(x1,x1), dot(x2,x2), dot(x3,x3)), 0.0);
 154   m = m * m;
 155   return 42.0 * dot( m*m, vec4( dot(p0,x0), dot(p1,x1),
 156                                 dot(p2,x2), dot(p3,x3) ) );
 157   }
 158
 159 #pragma glslify: export(snoise)